给 Vista 启动菜单添加 GRUB4DOS 项的批处理

在 XP 下，直接修改 boot.ini 即可添加 GRUB4DOS 项，但是在 Vista 下就没那么简单。
因公司和家里的电脑都是 XP + Vista ，前几日多次试验 GURB4DOS 的功能。之前在 添加这个菜单项都是手工添加，今天做了个批处理，共享出来吧。为防止菜鸟...，前面加了一些垃圾。

下面的批处理将自动添加 GRUB4DOS 启动项到 Vista 的启动菜单中：

===== Add_GRUB4DOS_Menu.bat =====

@echo off
echo 该批处理自动往 Vista 系统的启动菜单中添加 GRUB4DOS 的启动项。
echo 如果不是单一的 Vista（还有XP,2K），必须在 Vista 下运行。
echo 另外，需以管理员身份运行。
echo .
pause

ver | find "6.0." > NUL && goto START
ver | find "XP" > NUL && goto XP2K
ver | find "2000" > NUL && goto XP2K
goto EXIT

:XP2K
echo 不能在 WinXP 或 Win2000 中运行该批处理。
goto EXIT

REM ============= 以上的内容纯属...... ==============

:START
cls

bcdedit | find "\grldr.mbr" > NUL && echo 启动项中已有grub4dos，无需重复安装。&& goto EXIT
bcdedit /create /d "Boot From GRUB4DOS" /application bootsector >GrubID.txt
rem 上面欲增加的GRUB菜单名，可以修改为"GRUB For DOS"、"DOS + GHOST" 等等

for /f "tokens=2" %%i in (GrubID.txt) do set GrubID=%%i
del GrubID.txt > NUL
bcdedit /set %GrubID% device partition=%SystemDrive%
bcdedit /set %GrubID% path \grldr.mbr
bcdedit /displayorder %GrubID% /addlast

echo .
echo 上面应出现 3 个“操作成功完成。”
echo .
echo 请自行复制 grldr.mbr 到 %SystemDrive%\
echo .
echo 请自行复制 grldr 到 C:\
echo .
echo 根据需要，请自行复制其他有关文件，如 menu.lst, fonts, memdisk.gz 及背景图片等文件到相应位置。

:EXIT

====== THE END =====
各人使用 GRUB4DOS 的方式可能各有不同，所以没有自动复制 grldr.mbr 等文件，还是自己复制感觉稳妥吧。